FDIALLEL procedure

Forms the components of a diallel model for REML or regression (R.W. Payne).

No options

Parameters

`MALEPARENTS` = factors	Specifies the male parents
`FEMALEPARENTS` = factors	Specifies the female parents
`PARENTS` = matrices	Saves design matrices for the overall parental effects
`COMPPARENTS` = matrices	Saves comparison matrices for overall parental effects
`PUREVSCROSS` = factors	Saves factors to represent the comparison between pure and crossed lines
`CROSSPAIR` = factors	Saves factors to represent the comparison between types of pairs of parent (ignoring the individual genders)

Description

FDIALLEL forms the factors and matrices that are needed to specify and fit a diallel model using Genstat REML or regression.

The factors identifying the male and female parent of each line are specified by the MALEPARENTS and FEMALEPARENTS parameters, respectively. The PARENTS parameter saves a design matrix that can be used in REML to represent the overall effects of each parental line, and the COMPPARENTS parameter saves the transpose of the matrix. You can use COMPPARENTS as the third argument of the COMPARISON function to fit the parental effects in a Genstat regression model. The PUREVSCROSS parameter saves a factor to represent the comparison between pure and crossed lines, and the CROSSPAIR parameter saves a factor representing the comparison between types of pairs of parent (ignoring their individual genders).

The examples for FDIALLEL (which can be accessed by using the LIBEXAMPLE procedure or the Examples menu in Genstat for Windows) show how these factors and matrices can be used in Genstat REML and regression to generate the analyses of Hayman (1954) and Jones (1965), provided by the DIALLEL procedure. The terms in the DIALLEL analysis correspond to those in the FDIALLEL analysis as follows.

a: variation between mean effects of each parental line; this corresponds to PARENTS in REML, or COMP(Vdum; np; COMPPARENTS) in regression (where vdum is a dummy variate, containing any values, and np is the number of different types of parental line).

b1: assesses whether dominance is largely uni-directional; corresponds to PUREVSCROSS.

b2: estimates “asymmetry” i.e. if alleles at any one locus are not equally frequent; corresponds to PARENTS.PUREVSCROSS in REML, or COMP(Vdum; np; COMPPARENTS).PUREVSCROSS in regression.

b3: signifies that some dominance is peculiar to individual crosses; corresponds to CROSSPAIR.

c: variation between average maternal effects of each parental line; corresponds to FEMALEPARENT.

d: variation in the reciprocal differences not attributable to c; corresponds to MALEPARENT.FEMALEPARENT.

Options: none.

Parameters: MALEPARENTS, FEMALEPARENTS, PARENTS, COMPPARENTS, PUREVSCROSS, CROSSPAIR.

Action with `RESTRICT`

FDIALLEL ignores restrictions i.e. it forms the factors and matrices using all the units of MALEPARENTS and FEMALEPARENTS.

References

Hayman, B.I. (1954). The Analysis of Variance of Diallel Tables. Biometrics, 10, 235-244.

Jones, R.M. (1965). Analysis of Variance of the Half Diallel Table. Heredity, 20, 117-121.

Example

CAPTION  'FDIALLEL examples',\
         !t('Data from Hayman, B.I. (1954). Biometrics 10, 235-244.',\
         'Two blocks of 8 x 8 full (default setting of option METHOD)',\
         'diallel tables. Analysis over blocks giving block interactions.',\
         'Text provided to label rowcols.'); STYLE=meta,plain
TEXT     [VALUES=one,two,three,four,five,six,seven,eight] Parents
MATRIX   [ROWS=8; COLUMNS=8] Blockdat[1...2]
READ     [SERIAL=yes] Blockdat[]
276 156 322 250 162 193 222 152
136 166 164 134 102 150  96  90
246 158 416 213 160 222 128 166
318 132 218 272 138 195 108 124
150 124 164 164 156 158 100 114
182 136 204 216 133 174 112 120
174  86 194 142  86  92  58  94
152 128 158 136 126 114  84 142 :
302 178 274 246 140 204 254 154
142 175 136 128 128 174 116 114
242 174 360 178 140 208 160 154
204 138 206 210 130 192 138 176
180 140 156 146 176 192 104 170
186 146 202 222 150 166 136 176
162 100 162 100  98  84  48 142
154 138 140 144 124 112  96 166 :
DIALLEL  [PRINT=aov,griffing; LABELS=Parents] Blockdat[]
" put the data into a y-variate, form design factors Blocks, Male & Female "
FACTOR   [NVALUES=128; LABELS=Parents] Male,Female
FACTOR   [NVALUES=128; LEVELS=2] Blocks
GENERATE Blocks,Female,Male
VARIATE  [NVALUES=128] Y
EQUATE   Blockdat; Y
CAPTION  'Hayman analysis'; STYLE=meta
" form factors and matrices for analysis "
FDIALLEL MALEPARENTS=Male; FEMALEPARENTS=Female; PARENTS=Parent;\
         COMPPARENTS=Parentm; PUREVSCROSS=Pure_vs_Cross; CROSSPAIR=b3
VARIATE  [VALUES=128(0)] Parentv
MODEL    Y
FIT      [PRINT=accumulated; NOMESSAGE=aliasing]\ 
         Blocks  + (Pure_vs_Cross * COMP(Parentv;8;Parentm))\
         + b3 + Female + Male.Female\ 
         + Blocks.(Pure_vs_Cross * COMP(Parentv;8;Parentm))\ 
         + Blocks.(b3 + Female)
VCOMPONENTS [FIXED=Blocks  + (Pure_vs_Cross * Parent)\ 
         + b3 + Female + Male.Female\ 
         + Blocks.(Pure_vs_Cross * Parent)\ 
         + Blocks.(b3 + Female)]
REML     Y
CAPTION  'Griffing analysis'; STYLE=meta
" form factors and matrices for analysis "
FDIALLEL MALEPARENTS=Male; FEMALEPARENTS=Female; PARENTS=GCA;\
         COMPPARENTS=GCAm; CROSSPAIR=SCA
VARIATE  [VALUES=128(0)] GCAv
MODEL    Y
FIT      [PRINT=accumulated; NOMESSAGE=aliasing]\
         Blocks + COMP(GCAv;8;GCAm) + SCA + Female + Male.Female
VCOMPONENTS [FIXED=Blocks + GCA + SCA + Female + Male.Female]
REML     Y

CAPTION  !t('Data from Jones, R.M. (1965). Heredity 20, 117-121.',\
         'Single block of half diallel.')
MATRIX   [ROWS=4; COLUMNS=4] Data
READ     Data
33.9 42 35.6 38.7
0    31 36.7 39.1
0    0  30   34.5
0    0  0    32.8 :
DIALLEL [PRINT=aov; METHOD=half] Data
" put data into a y-variate, and form design factors Blocks, Male & Female "
FACTOR   [NVALUES=16; LEVELS=4] male,female
GENERATE male,female
VARIATE  [NVALUES=16] y
EQUATE   Data; y
" remove the empty lower-triangle of zeros "
SUBSET   [y.GT.0] male,female,y
CAPTION  'Hayman analysis'; STYLE=meta
" form factors and matrices for analysis "
FDIALLEL MALEPARENTS=male; FEMALEPARENTS=female; PARENTS=parent;\
         COMPPARENTS=parentm; PUREVSCROSS=pure_vs_cross; CROSSPAIR=b3
CALCULATE parentv = y - y
MODEL    y
FIT      [PRINT=accumulated; NOMESSAGE=aliasing]\ 
         (COMP(parentv;3;parentm) * pure_vs_cross)  + b3
" regression analysis shows that b3 has to be used as the residual "
VCOMPONENTS [FIXED=parent * pure_vs_cross]
REML     y

Updated on March 8, 2019

Tagged: Command Procedures

Was this article helpful?

Yes No